home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Aminet 5
/
Aminet 5 - March 1995.iso
/
Aminet
/
mus
/
misc
/
xmodule30.lha
/
XModule
/
Install_XModule
< prev
next >
Wrap
Text File
|
1995-01-02
|
7KB
|
293 lines
; $VER: Install_XModule 2.8 (5.5.94)
;
; Installer script for XModule
;***************************************************************************
; English strings
;***************************************************************************
(set default_lang 1)
(set #askdirstr (cat "In which directory should XModule be installed?\n"
"(A drawer called \"XModule\" will be created)"))
(set #askdir-help (cat "Please select the directory or partition in which you would like "
"XModule installed (a drawer named \"XModule\" will be created "
"in the directory you have selected).\n\n\n"
@askdir-help))
(set #askdocformat "Please select which documentation format(s) to install:")
(set #magicwb-str (cat "Do you want MagicWB-style icons for XModule?\n"
"(Requires MagicWB installed in your system)\n\n"
"MagicWB is a collection of fine 8 color icons made by "
"Martin Huttenloher. These icons require a special palette, "
"otherwise they look awful.\n"))
(set #magicwb-help "Answer \"Yes\" only if your system preferences are properly set.")
(set #docformat-help (cat "Choose AmigaGuide documentation if you are running "
"WorkBench 2.1 or higher and/or you have Commodore AmigaGuide "
"hypertext reader installed. Otherwhise choose the normal "
"documentation.\n\n"
@askoptions-help))
(set #toolman-brush (cat "This distribution includes a brush image suitable for ToolManager docks.\n\n"
"Do you want to copy it to your brush drawer?"))
(set #toolman-help (cat "ToolManager is a program by Stefan Backer which extends Workbench "
"usability allowing the user to start applications through AppIcons, AppMenus and "
"small windows filled with buttons called docks.\n\n"
"If you answer \"Yes\", you will be asked in which directory the brush image "
"should be copied.\n\n"))
(set #toolman-askdir "In which directory should the ToolManager image be copied?")
(set #bad-kick "Sorry, XModule requires Kickstart version 2.04 or higher.")
(set #makingdir "Creating XModule directory...")
(set #copying-xmodule "Copying XModule...")
(set #copying-doc "Copying ASCII Documentation...")
(set #copying-guide "Copying AmigaGuide Documentation...")
(set #copying-brush "Copying ToolManager image...")
(set #bonusmod-str (cat "XModule distribution contains a fine bonus module "
"made by FBY (Fabio Barzagli).\n\n"
"Do you want it copied to your modules drawer?"))
(set #makingmoddir "Creating Modules Directory...")
(set #copying-mods "Copying Bonus Modules...")
;***************************************************************************
; Make sure we are running under a 2.04 ROM
;***************************************************************************
(set sys-ver (/ (getversion) 65536))
(if (< sys-ver 37)
(abort #bad-kick)
)
(welcome) ; Say Hi!
;***************************************************************************
; Ask user where he wants the XModule files
;***************************************************************************
(set @target-dir
(askdir
(prompt #askdirstr)
(help #targetsel #askdir-help)
(default @default-dest)
)
)
(set @target-dir (tackon @target-dir "XModule"))
(set @default-dest @target-dir)
;***************************************************************************
; Make the XModule directory
;***************************************************************************
(makedir
@target-dir
(infos)
(help @makedir-help)
(prompt #makingdir)
)
;***************************************************************************
; Ask for MagicWB icons
;***************************************************************************
(if (askbool
(prompt #magicwb-str)
(help #magicwb-help)
)
(set @magic-icons 1)
)
;***************************************************************************
; Copy the XModule executable and its icon
;***************************************************************************
(copyfiles
(prompt #copying-xmodule)
(source "XModule")
(dest @target-dir)
(infos)
)
(if (= @magic-icons 1)
(copyfiles
(source "MagicWB_Icons/XModule.info")
(dest @target-dir)
)
)
(complete 20)
;***************************************************************************
; Copy default icon for modules & instruments
;***************************************************************************
(if (= @magic-icons 1)
(
(copyfiles
(source "MagicWB_Icons/")
(choices "def_Module.info" "def_Instrument.info")
(dest @target-dir)
)
)
( ; else
(copyfiles
(source "")
(choices "def_Module.info" "def_Instrument.info")
(dest @target-dir)
)
)
)
(tooltype
(dest (tackon @target-dir "def_Module"))
(setdefaulttool (tackon @target-dir "XModule"))
(noposition)
)
;***************************************************************************
; Copy documentation files
;***************************************************************************
(complete 50)
(set doc-choice (askoptions
(prompt #askdocformat)
(help #docformat-help)
(choices
"AmigaGuide Documentation"
"ASCII Documentation"
)
(default (if (OR (exists "SYS:Utilities/AmigaGuide") (exists "SYS:Utilities/MultiView")) 1 2))
))
(if (BITAND doc-choice 1)
(
(copyfiles
(prompt #copying-guide)
(source "XModule.guide")
(dest @target-dir)
(infos)
)
(if (= @magic-icons 1)
(copyfiles
(source "MagicWB_Icons/XModule.guide.info")
(prompt #copying-xmodule)
(dest @target-dir)
)
)
(if (< sys-ver 39)
(tooltype
(dest (tackon @target-dir "XModule.guide"))
(setdefaulttool "SYS:Utlities/AmigaGuide")
)
)
))
(if (BITAND doc-choice 2)
(
(copyfiles
(prompt #copying-doc)
(source "XModule.doc")
(dest @target-dir)
(infos)
)
(if (= @magic-icons 1)
(copyfiles
(source "MagicWB_Icons/XModule.doc.info")
(prompt #copying-xmodule)
(dest @target-dir)
)
)
))
(complete 70)
;***************************************************************************
; Copy ToolManager brush
;***************************************************************************
(if (= @magic-icons 1)
(if (askbool
(prompt #toolman-brush)
(help #toolman-help))
(
(set @brush-dir
(askdir
(prompt #toolman-askdir)
(help #askdir-help)
(default "SYS:Prefs/")
)
)
(copyfiles
(source "MagicWB_Icons/XModule.brush")
(prompt #copying-brush)
(dest @brush-dir)
)
)
)
)
(complete 80)
;***************************************************************************
; Copy bonus module
;***************************************************************************
(if (askbool (prompt #bonusmod-str) (help @askbool-help))
(
(makedir
(tackon @target-dir "Modules")
(infos)
(prompt #makingmoddir)
(help @makedir-help)
)
(copyfiles
(prompt #copying-mods)
(source "BonusModules")
(dest (tackon @target-dir "Modules"))
(all)
(infos)
)
(if (= @magic-icons 1)
(copyfiles
(source "MagicWB_Icons/def_Module.info")
(prompt #copying-mods)
(dest (tackon @target-dir "Modules"))
(newname "FBY-Winning.mod.info")
)
)
)
)
(complete 100)